AX 2012 - Creare una ledgerDimension partendo dai singoli segmenti

In questo post vediamo come creare una ledgerDimension partendo dai singoli segmenti. In questo esempio esempio abbiamo a  disposizione il conto e il centro di costo. Il codice sottostante ritorna il recId da assegnare al campo ledgerdimension:

 static void CreateLedgerDimension(Args _args)  
 {  
   LedgerDimensionAccount ledgerDimension;  
   LedgerDimensionAccount mainAccDimension;  
   RefRecId        defaultDimRecId;  
   RecId createDefaultDimension()  
   {  
     DimensionAttributeValueSetStorage  valueSetStorage = new DimensionAttributeValueSetStorage();  
     DimensionDefault          result;  
     int           i;  
     DimensionAttribute   dimensionAttribute;  
     DimensionAttributeValue dimensionAttributeValue;  
     container        conAttr = ["CentroCosto"]; //array dei nomi delle dimensioni  
     container        conValue = ["1100"];    //container dei valori  
     str           dimValue;  
     for (i = 1; i <= conLen(conAttr); i++)  
     {  
       dimensionAttribute = dimensionAttribute::findByName(conPeek(conAttr,i));  
       if (dimensionAttribute.RecId == 0)  
       {  
         continue;  
       }  
       dimValue = conPeek(conValue,i);  
       if (dimValue != "")  
       {  
         dimensionAttributeValue =  
             dimensionAttributeValue::findByDimensionAttributeAndValue(dimensionAttribute,dimValue,false,true);  
         valueSetStorage.addItem(dimensionAttributeValue);  
       }  
     }  
     result = valueSetStorage.save();  
     info(Strfmt("%1",result));  
     return result;  
   }  
   //quì la dimensione relativa al solo main account  
   mainAccDimension = DimensionStorage::getDefaultAccountForMainAccountNum("3090");   
   //il metodo createDefaultDimension crea la dimensione serve per costruire il resto del segmento  
   defaultDimRecId = createDefaultDimension();  
   //il metodo serviceCreateLedgerDimension effettua il merge delle dimensioni e ristorna il recId realtivo  
   ledgerDimension = DimensionDefaultingService::serviceCreateLedgerDimension(mainAccDimension,defaultDimRecId);  
   info(Strfmt("%1",ledgerDimension));  
 }  

Il risultato che andremo ad attenere sarà:

AX 2012 - How to: Visualzzare dinamicamente le dimensioni inventariali su form

In questo link interessante how to per la visualizzazione dinamica delle dimensioni inventariali in un form.

AX 2012 - parm di lookup multiselezione su data contract

Piccola pillola per chi utilizza lookup multiselezione sui SOF (SysOperationFramework).

Per pilotare i parametri di una lookup multiselezione nella vostra dialog di tipo SOF tramite la classe di contratto, dovrete gestire il valore tramite lista e aggiungere il seguente codice nell'intestazione del metodo di parm per non incappare in errori:

 AifCollectionTypeAttribute("return",Types::String)  

Esempio su StackOverflow:

http://stackoverflow.com/questions/18498128/report-multivalue-parameter

AX 2009 - Abilitare i filtri (Ctrl +g) su lookup via X++

In questo post vediamo come abilitare via codice i filtri wildcard sui controlli grid delle lookup di AX 2009. In questo caso la richiesta è di poter vedere di default i filtri aperti non appena si apre la lookup sul campo selezionato. La difficoltà stà nel fatto che non abbiamo un vero e proprio form, ma solo il form generato da standard quando si apre una look up. Per fare ciò occorrerà modificare la classe SysSetupFormRun che rappresenta l'unico punto in cui intercettare l'apertura della lookup: il post presente Quì è stato di grande aiuto =)

Per prima cosa effettuiamo l'override del metodo Run della classe SysSetupFormRun  :

 public void run()  
 {  
   object     obj;  
   SysSetupFormRun SysSetupFormRun;  
   int       i,classId;  
   FormControl   control;  
   #define.Ctrl_g(2855)  
   ;  
   super();  
   obj = this.args().caller();  
   if(obj)  
   {  
     classId = classIdget(obj);  
   }  
   if(classId == className2id(classStr(SysSetupFormRun)))  
   {  
     SysSetupFormRun = obj;  
     control = SysSetupFormRun.selectedControl();  
     if(SysSetupFormRun.name() == formStr(<form string>l))  
     {  
       if(control.id() == <id del controllo nel form> && this.CRFindTopmostGrid())  
       {  
         this.task(#Ctrl_g);  
       }  
     }  
   }  
 }  

Il metodo CRFindTopmostGrid() cicla i tutti i controlli del form chiamante:

 private boolean CRFindTopmostGrid()  
 {  
   FormControl fc;  
   int i;  
   ;  
   for (i=1;i<=this.design().controlCount();i++)  
   {  
     fc = this.design().controlNum(i);  
     if (this.CRFindGrid(fc))  
     {  
       return true;  
     }  
   }  
   return false ;  
 }  

mentre il metodo CRFinfGrid() verifica se il controllo passato è di tipo Grid:

 private boolean CRFindGrid(FormControl fc)  
 {  
   FormGridControl fgrc;  
   FormGroupControl fgc;  
   FormTabControl ftc;  
   FormTabPageControl ftpc;  
   str controlStr,s;  
   int i, controlId;  
   Struct struct;  
   ;  
   // check to see what kind of control it is  
   controlStr = fc.toString();  
   if(strScan(controlStr,"FormGridControl",1,strLen(controlStr)))  
   {  
     if (fc.visible())  
     {  
       fgrc = fc;  
       fgrc.enter();  
       return true;  
     }  
   }  
   else if(strScan(controlStr, "FormGroupControl",1,strLen(controlStr)))  
   {  
     fgc = fc;  
     for (i=1;i<=fgc.controlCount();i++)  
     {  
       if (this.CRFindGrid(fgc.controlNum(i)))  
       {  
         return true;  
       }  
     }  
   }  
   //  
   else if(strScan(controlStr, "FormTabControl",1,strLen(controlStr)))  
   {  
     ftc = fc;  
     for (i=1;i<=ftc.controlCount();i++)  
     {  
       if (this.CRFindGrid(ftc.controlNum(i)))  
       {  
         return true;  
       }  
     }  
   }  
   else if(strScan(controlStr, "FormTabPageControl",1,strLen(controlStr)))  
   {  
     ftpc = fc;  
     for (i=1;i<=ftpc.controlCount();i++)  
     {  
       if (this.CRFindGrid(ftpc.controlNum(i)))  
       {  
         return true;  
       }  
     }  
   }  
   return false;  
 }  

Per ottenere l'id del controllo che apre la lookup possiamo usare il seguente job che dato un form ci fornisce gli id e i nomi di tutti i componenti grafici:

 static void recurseOverAllFormControls(Args _args)  
 {  
   Form form = new Form(formstr(CLU_VendInvoiceJournal));  
   void recurse(Object _parent, int _depth = 1)  
   {  
     int   i;  
     str   name;  
     str   caption;  
     str   dashes;  
     int   id;  
     ;  
     // Used for making it pretty  
     //-->  
     i = _depth;  
     while (i)  
     {  
       dashes += '-';  
       i--;  
     }  
     //<--  
     // Used for example of how to use data  
     //-->  
     if (SysTest::hasMethod(_parent, identifierStr(caption)))  
       caption = _parent.caption();  
     if (SysTest::hasMethod(_parent, identifierStr(name)))  
       name = _parent.name();  
      if (SysTest::hasMethod(_parent, identifierStr(id)))  
       id = _parent.id();  
     info(strfmt("%1%2[%3](%4)(%5)", _depth, dashes, name, caption, id));  
     //<--  
     // Escape condition!  
     if (_parent.controlCount() == 0)  
       return;  
     // Recursive statement  
     for (i=1; i<=_parent.controlCount(); i++)  
       recurse(_parent.controlNum(i), _depth+1);  
   }  
   ;  
   recurse(form.design());  

AX 2012 - Lookup su dialog SSRS: Utilizzo classe UI Builder

In moltissimi casi può sorgere la necessità di aggiungere un parametro che esegua una lookup su un campo di una tabella nella finestra di dialog di un report.

Per prima cosa occorre modificare (o creare in caso non esista) la classe UI builder del report. Questa classe è necessaria quando si desidera personalizzare la dialog di un report.
In sintesi ci consente di aggiungere controlli (visibilità, abilitazione...) e lookup personalizzati ai parametri impostati nella classe Data contract del report stesso. Si presuppone la creazione quindi del metodo parm nella data contract del campo che vogliamo "lookupare".

La classe builder che andremo a creare (se non esiste già) deve innanzitutto estendere SrsReportDataContractUIBuilder. Vediamo, con un banalissimo esempio, la creazione di questa classe per un report che ha come parametro il codice cliente. Si vuole visualizzare una lookup nella SalesTable di tutti gli ordini di quel cliente

 class SimpleDemoUIBuilder extends SrsReportDataContractUIBuilder  
 {  
   DialogField dialogCustAccount;
   DialogField dialogSalesOrders;  
   SimpleDemoContract contract;  
 }  

Può essere utile effettuare l'override del metodo build per impostare la data contract e il dialog field dichiarati nella class declaration...

 public void build()  
 {  
   contract = this.dataContractObject();  
   dialogCustAccount = this.addDialogField(methodStr(SimpleDemoContract,parmCustAccount),contract);
 }  

...piuttosto che eseguire tutto nel metodo postBuild:

 public void postBuild()  
 {  
   DialogField             dialogCostingVersionId;  
   SimpleDemoContract      contract;
  
   super();
  
   contract= this.dataContractObject();  
   dialogCustAccount = this.addDialogField(methodStr(SimpleDemoContract,parmCustAccount),contract);
   dialogSalesOrders = this.addDialogField(methodStr(SimpleDemoContract,parmSalesOrders),contract);   
   .....
   dialogSalesOrders.registerOverrideMethod(methodStr(FormStringControl, lookup), methodStr(SimpleDemoUIBuilder, salesOrdersLookup), this);
  
 }  

dove l'ultima riga servirà proprio a far si che la dialog esegua il metodo di lookup sottostante:

  private void salesOrdersLookup(FormStringControl _salesOrdersLookup)  
 {  
      Query query = new Query();  
      QueryBuildDataSource qbds_SalesTable;  
      SysTableLookup sysTableLookup;  
    
      if (_salesOrdersLookup != null)
      {
                 sysTableLookup = SysTableLookup::newParameters(tableNum(SalesTable), _salesOrdersLookup);  
                 qbds_SalesTable = query.addDataSource(tableNum(SalesTable)); 
                 sysTableLookup.addLookupfield(fieldnum(SalesTable, SalesId), true);
     
                 qbds_SalesTable.addRange(fieldNum(SalesTable,CustAccount)).value(queryValue(contract.parmCustAccount());
                 sysTableLookup.parmQuery(query);  
                 // Perform the lookup  
                 sysTableLookup.performFormLookup();  
      }
 }    

Dove si effettuerà il range con il metodo parm (che in questo caso funge da getter), creato nella data contract.

AX 2012 - SSRS valore assente per un nuovo parametro

Quando aggiungiamo un parametro al form di lancio dei report in AX 2012, può capitare che questo valore al lancio sia nullo, ma se non gestiamo questa eventualità (impostando le proprietà adeguate lato Visual Studio) allora avremo il seguente messaggio di errore:

The 'ParameterName' parameter is missing a value

In questo caso impostare le giuste proprietà in Visual Studio:

Allow Blank       True

Nullable            True

 nel parametro avente il problema (ed eseguire il deploy) potrebbe non bastare!

In questo caso occorre agire come brillantemente segnalato in questo blog, dove segnala i vari metodi per far "sentire" questa modifica:

blog con i metodi

Method I.

Force the update of the properties by renaming the parameter

1. Open the report for editing in Visual Studio.

2. Expand the Parameters node and rename the affected parameter to ParameterName1.

3. Set Allow Blank and Nullable to True if not already set.

4. Deploy the report.

5. Rename the parameter back to ParameterName.

6. Deploy the report.

Method II.

Recreate the parameter in Visual Studio and set the properties as required before deploying the report

1. In AOT, expand the SSRS Reports node, expand the Reports node and locate the report.

2. Right click on the report and select Delete. This will remove all customizations to the report from the current model/layer so make sure you create a backup if you think you might want to return to them.

3. Right click on the report and select Deploy element. You should now be at the point where you did not receive this error.

4. Open the report for editing in Visual Studio and refresh the dataset. The parameter will be created under theParameters node. Do not deploy the report at this point.

5. Set Allow Blank and Nullable to True.

6. Deploy the report.

Method III.

Modify the properties of the parameter editing the report in the Reporting Services Report Manager

1. Open the report for editing in Visual Studio.

2. Expand the Parameters node and locate the affected parameter.

3. Set Allow Blank and Nullable to True if not already set.

4. Deploy the report.

5. Open Reporting Services Report Manager, in the Parameters properties page of the report, verify that Has defaultand Null check boxes are selected for the affected parameter.

6. Press Apply to save any changes.

AX 2012 - Default dimension

In questo post vediamo come gestire le dimensioni finanziare nelle anagrafiche cliente/fornitore. Il job sottostante scrive nella defualt dimension "CLIENTE" il valore del custAccount:

 static void CreateDefaultDimension(Args _args)  
 {  
   DimensionAttributeValueSetStorage  valueSetStorage = new DimensionAttributeValueSetStorage();  
   DimensionDefault          result;  
   CustTable        custTable = CustTable::find('‪‪‪I01-000001',true);  
   int           i;  
   DimensionAttribute   dimensionAttribute;  
   DimensionAttributeValue dimensionAttributeValue;  
   container        conAttr = ["CLIENTE"]; //nome della dimensione  
   container        conValue = ["I01-000001"]; //valore da inserire  
   str           dimValue;  
   /* per evitare l'hard code 'CLIENTE' possiamo cercare nella tabella dimensionAttribute per   
   backEntityType che è un table num. Nel caso cliente tableNum sarà = tableNum(DimAttributeCustTable)  
   mentre nel caso fornitori tableNum(DimAttributeVendTable)*/  
   for (i = 1; i <= conLen(conAttr); i++)  
   {  
     dimensionAttribute = dimensionAttribute::findByName(conPeek(conAttr,i));  
     if (dimensionAttribute.RecId == 0)  
     {  
       continue;  
     }  
     dimValue = conPeek(conValue,i);  
     if (dimValue != "")  
     {  
       dimensionAttributeValue =  
           dimensionAttributeValue::findByDimensionAttributeAndValue(dimensionAttribute,dimValue,false,true);  
       valueSetStorage.addItem(dimensionAttributeValue);  
     }  
   }  
   result = valueSetStorage.save();  
   ttsBegin;  
   custTable.DefaultDimension = result;  
   custTable.doUpdate();  
   ttsCommit;  
 }  

Prima dell'esecuzione del job:

Dopo l'esecuzione:

Una diversa soluzione, un pò più complessa l'ho trovata quì